#!/usr/bin/mawk -We
# *********************************************************************
#  Written by and copyright Carlo Strozzi <carlos@linux.it>.
#
#  envtolist: converts environment variables into a NoSQL list.
#  Copyright (C) 1998-2001 Carlo Strozzi <carlos@linux.it>
# 
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2 of the License, or
#  (at your option) any later version.
# 
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
# 
#  You should have received a copy of the GNU General Public License
#  along with this program; if not, write to the Free Software
#  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
#  2001-01-03 Ported to NoSQL v3
#  2001-04-17 Added inline help
#  2001-08-17 Added stdio portability
#
#  $Id$
# *********************************************************************

BEGIN {
  NULL = ""; OFS = "\t"

  while (ARGV[++i] != NULL) {
    if (ARGV[i] == "-m" || ARGV[i] == "--match") m_pattern = ARGV[++i]
    else if (ARGV[i] == "-d" || ARGV[i] == "--delete") {
      remove = 1; d_pattern = ARGV[++i]
    }
    else if (ARGV[i] == "-b" || ARGV[i] == "--blank") {
      blank = 1; b_pattern = ARGV[++i]
    }
    else if (ARGV[i] == "-x" || ARGV[i] == "--debug") debug = 1
    else if (ARGV[i] == "-s" || ARGV[i] == "--strip-names") {
      strip_names = 1; s_pattern = ARGV[++i]
    }
    else if (ARGV[i] == "-p" || ARGV[i] == "--prefix") prefix = ARGV[++i]
    else if (ARGV[i] == "-t" || ARGV[i] == "--trim") trim = 1
    else if (ARGV[i] == "-c" || ARGV[i] == "--chomp") chomp = 1
    else if (ARGV[i] == "-C" || ARGV[i] == "--chop") chop = 1
    else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
       system("grep -v '^#' @NOSQLPATH@/nosql/help/envtolist.txt")
       rc = 1
       exit(rc)
    }
  }

  ARGC = 1				# Fix argv[]

  if (debug) {
    print "-m pattern: " m_pattern    > "@STDERR@"
    print "-d pattern: " d_pattern    > "@STDERR@"
    print "-b pattern: " b_pattern    > "@STDERR@"
    print "-s pattern: " s_pattern    > "@STDERR@"
  }

  if (m_pattern == NULL) m_pattern = ".*"

  if (!chop) printf("\n")		# Print list-start separator.

  for (env in ENVIRON) {
    if (env !~ m_pattern) continue

    # Always skip rc(1) functions and NoSQL-specific stuff.
    if ( env ~ /^fn_/ || env ~ /^_nosql_/ || env == "NSQPGPPASS" ) continue

    # Skip invalid variable names. They may occur when we receive
    # them from a WWW Browser.
    if (env !~ /^[A-Za-z][A-Za-z0-9_]+$/) {
      print "envtolist: bad variable name " env > "@STDERR@"
      continue
    }

    # Honour the '-s' switch.
    dd = env
    if (strip_names) gsub(s_pattern, NULL, dd)

    # In case we stripped the whole name.
    if (dd == NULL) continue

    printf("%s%s\t", prefix, dd)

    var = ENVIRON[env]

    # Honour '-d' and '-b' first.
    if (remove) gsub(d_pattern, NULL, var)
    if (blank) gsub(b_pattern, " ", var)

    if (trim) {
       sub(/^ +/, NULL, var)
       sub(/ +$/, NULL, var)
    }

    # Continuation lines must be properly formatted.
    gsub(/\n/, "\n ", var)
    printf("%s\n", var)
  }
  if (!chomp) printf("\n")		# Print list-end separator.
}

#
# End of program.
#
