#!/usr/bin/mawk -We
# *********************************************************************
#  Written by and copyright Carlo Strozzi <carlos@linux.it>.
#
#  number: inserts a unique record identifier into a table.
#  Copyright (C) 2001 Carlo Strozzi <carlos@linux.it>
# 
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2 of the License, or
#  (at your option) any later version.
# 
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
# 
#  You should have received a copy of the GNU General Public License
#  along with this program; if not, write to the Free Software
#  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
#  2001-03-24 Alpha code.
#  2001-03-27 Added option '-d'
#  2001-04-17 Added inline help
#  2001-08-17 Added stdio portability
#
#  $Id$
# *********************************************************************

BEGIN {
  NULL = ""; FS = OFS = "\t"; key_name = "id"

  while (ARGV[++i] != NULL) {
    if (ARGV[i] == "-l" || ARGV[i] == "--last") pick_last = 1
    else if (ARGV[i] == "-N" || ARGV[i] == "--no-header") no_hdr = 1
    else if (ARGV[i] == "-K" || ARGV[i] == "--key") key_name = ARGV[++i]
    else if (ARGV[i] == "-d" || ARGV[i] == "--delimiter") dlm = ARGV[++i]
    else if (ARGV[i] == "-i" || ARGV[i] == "--input") i_file = ARGV[++i]
    else if (ARGV[i] == "-o" || ARGV[i] == "--output") o_file = ARGV[++i]
    else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
       system("grep -v '^#' @NOSQLPATH@/nosql/help/number.txt")
       rc = 1
       exit(rc)
    }
    else target_cols[ARGV[i]] = ARGV[i]
  }

  ARGC = 1					# Fix argv[]

  if (o_file == NULL) o_file = "@STDOUT@"
  if (i_file != NULL) { ARGV[1] = i_file; ARGC = 2 }
}

#
# Main loop
#

NR == 1 {
  # Load the column position array.
  while (++p <= NF) {

    # Unless '-l' was specified, make sure we pick the first occurrence
    # of duplicated column names (it may happen after a join).

    if (P[$p] == NULL) auto_col = auto_col " " $p

    if (pick_last) { P[$p] = p; N[p] = $p }
    else {
      if (P[$p] == NULL) { P[$p] = p; N[p] = $p }
    }
  }

  $0 = key_name OFS $0			# Insert the key column.
  if (!no_hdr) print > o_file
  gsub(/[^\t]/, "-")
  dashline = $0
  next
}

# Dashline
NR == 2 { if (!no_hdr) print dashline > o_file; next }

# Table body.
{
  out = k = NULL
  for (i=1; i<=NF; i++) {
      if (i > 1) out = out OFS
      if (target_cols[N[i]] != NULL) {
	 if ($i == NULL)
	    print "number: invalid N[i]=NULL at record No. " \
	    NR-2 > "@STDERR@" 
	 if (k != NULL) k = k dlm
	 k = k $i
      }
      out = out $i
  }
  if (k == NULL) k = NR-2	# Resort to a generic id if necessary.
  print k OFS out > o_file
}

#
# End of program.
#
